net-misc/meganz-sdk: update live

Signed-off-by: Alfred Wingate <parona@protonmail.com>

net-misc/meganz-sdk/meganz-sdk-9999.ebuild

@@ -1,107 +1,120 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
+
+inherit cmake flag-o-matic
 
-inherit flag-o-matic qmake-utils autotools db-use
-if [[ -z ${PV%%*9999} ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/${PN%-*}/${PN#*-}.git"
-else
-	SRC_URI="https://github.com/meganz/sdk/archive/v${PV}d.tar.gz -> ${P}.tar.gz"
-	S="${WORKDIR}/sdk-${PV}d"
-	RESTRICT="primaryuri"
-	KEYWORDS="~amd64 ~x86"
-fi
 DESCRIPTION="MEGA C++ SDK"
 HOMEPAGE="https://github.com/meganz/sdk"
 
-LICENSE="BSD-2"
-SLOT="0/30701"
-IUSE="examples ffmpeg freeimage fuse hardened inotify libuv mediainfo qt raw +sqlite test"
-REQUIRED_USE="
-	examples? ( sqlite )
-	fuse? ( examples )
-"
-# tests require a working mega.nz account and login details provided via $MEGA_EMAIL and $MEGA_PWD
-RESTRICT+=" test"
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/meganz/sdk.git"
+else
+	SRC_URI="https://github.com/meganz/sdk/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/sdk-${PV}"
+	KEYWORDS="~amd64"
+fi
 
+LICENSE="BSD-2"
+SLOT="0/${PV}"
+IUSE="examples ffmpeg freeimage fuse libuv mediainfo qt test"
+
+RESTRICT="!test? ( test )"
+
+# <ffmpeg-6: https://github.com/meganz/sdk/issues/2635
 RDEPEND="
-	dev-libs/crypto++
-	sys-libs/zlib
-	dev-libs/libpcre:3[cxx]
-	dev-libs/openssl:0
-	net-dns/c-ares
+	dev-db/sqlite:3
+	dev-libs/crypto++:=
+	dev-libs/icu:=
+	dev-libs/libsodium:=
+	dev-libs/openssl:=
+	net-dns/c-ares:=
 	net-misc/curl
-	sqlite? ( dev-db/sqlite:3 )
-	!sqlite? ( sys-libs/db:*[cxx] )
-	examples? (
-		sys-libs/readline:0
-		fuse? ( sys-fs/fuse:0 )
-	)
+	ffmpeg? ( <media-video/ffmpeg-6 )
 	freeimage? ( media-libs/freeimage )
-	libuv? ( dev-libs/libuv )
-	dev-libs/libsodium
-	mediainfo? ( media-libs/libmediainfo )
-	ffmpeg? ( media-video/ffmpeg )
-	raw? ( media-libs/libraw )
+	fuse? ( sys-fs/fuse )
+	libuv? ( dev-libs/libuv:= )
+	mediainfo? (
+		media-libs/libmediainfo
+		media-libs/libzen
+	)
+	qt? ( dev-qt/qtcore:5 )
 "
 DEPEND="
 	${RDEPEND}
-	test? ( dev-cpp/gtest )
+	sys-libs/readline
 "
 
-pkg_setup() {
-	use sqlite || append-cppflags "-I$(db_includedir)"
-}
-
 src_prepare() {
-	default
-	use qt && sed \
-		-e '/SOURCES += src\// s:+:-:' \
-		-e '/!exists.*config.h/ s:!::' \
-		-e 's:CONFIG(USE_MEGAAPI) {:&\nLIBS += -lmega:' \
-		-e '/^unix:!macx {/,/^}/d' \
-		-i bindings/qt/sdk.pri
-	use test && sed \
-		-e 's:\$(GTEST_DIR)/lib/lib\([^ ]\+\)\.la:-l\1:g' \
-		-e 's: tests/tool_purge_account::' \
-		-i tests/include.am
-	eautoreconf
+	# 1. Mismatched pkgconfig file names
+	# 2. Symbols still needed publically when linking library
+	sed -i \
+		-e '/pkg_check_modules/ s/libcrypto++/libcryptopp/' \
+		-e '/target_link_libraries(SDKlib/ { /\(curl\|sodium\)/ s/PRIVATE/PUBLIC/ }' \
+		contrib/cmake/modules/sdklib_libraries.cmake || die
+
+	sed -i \
+		-e 's|DESTINATION cmake|DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake|' \
+		-e 's|DESTINATION pkgconfig|DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig|' \
+		contrib/cmake/modules/sdklib_target.cmake || die
+
+	# examples use readline symbols
+	sed -i \
+		-e 's/target_link_libraries(megacli PRIVATE MEGA::SDKlib)/target_link_libraries(megacli PRIVATE MEGA::SDKlib PkgConfig::readline)/' \
+		examples/CMakeLists.txt || die
+
+	cmake_src_prepare
 }
 
 src_configure() {
-	local myeconfargs=(
-		--enable-chat
-		$(use_enable inotify)
-		$(use_enable hardened gcc-hardening)
-		$(use_with libuv)
-		$(use_with !sqlite db)
-		$(use_with sqlite)
-		$(use_enable examples)
-		$(use_enable test tests)
-		$(use_with freeimage)
-		$(use_with fuse)
-		$(use_with mediainfo libmediainfo)
-		$(use_with ffmpeg)
-		$(use_with raw libraw)
+	# building with DEBUG disabled isn't tested apparently
+	# https://github.com/meganz/sdk/issues/2658
+	append-cppflags -DDEBUG=1
+
+	local mycmakeargs=(
+		# CMakeLists.txt
+		# contrib/cmake/modules/sdklib_options.cmake
+
+		-DENABLE_ISOLATED_GFX=OFF # required freeimage + doesn't properly link libz
+		-DENABLE_QT_BINDINGS=$(usex qt) # doesn't get installed
+		-DENABLE_SDKLIB_EXAMPLES=$(usex examples)
+		-DENABLE_SDKLIB_TESTS=$(usex test)
+		-DENABLE_SDKLIB_WERROR=OFF
+		-DUSE_FFMPEG=$(usex ffmpeg)
+		-DUSE_C_ARES=ON
+		-DUSE_FREEIMAGE=$(usex freeimage)
+		-DUSE_LIBUV=$(usex libuv)
+		-DUSE_MEDIAINFO=$(usex mediainfo)
+		-DUSE_OPENSSL=ON
+		-DUSE_PDFIUM=OFF # unpackaged
+		-DUSE_READLINE=ON
+		-DWITH_FUSE=$(usex fuse)
 	)
-	use test && myeconfargs+=(
-		--with-gtest="${EPREFIX}/usr"
-	)
-	econf "${myeconfargs[@]}"
+	cmake_src_configure
 }
 
 src_test() {
-	export MEGA_EMAIL MEGA_PWD MEGA_EMAIL_AUX="${MEGA_EMAIL}" MEGA_PWD_AUX="${MEGA_PWD}"
-	default
+	set -- "${BUILD_DIR}"/tests/unit/test_unit
+	einfo ${@}
+	${@} || die
+
+	# integration test require a mega account and will be destructive, which is why they aren't run.
+	# IMPORTANT: the main account must be empty (Cloud & Rubbish) before starting the test and it will be purged at exit.
+	# Both main and auxiliar accounts shouldn't be contacts yet and shouldn't have any pending contact requests.
+	# Set your login credentials as environment variables:
+	# * $MEGA_EMAIL and $MEGA_PWD (and $MEGA_EMAIL_AUX / $MEGA_PWD_AUX for shares * contacts)
 }
 
 src_install() {
-	default
+	cmake_src_install
+
 	doheader -r include/mega
 
-	use qt || return
+	if use qt; then
+		dolib.so "${BUILD_DIR}"/bindings/qt/libSDKQtBindings.so
 		insinto /usr/share/${PN}/bindings/qt
-	doins bindings/qt/*.{h,cpp,pri}
+		doins bindings/qt/*.{h,cpp}
+	fi
 }