net-misc/meganz-sdk: Fixed and bumped

Signed-off-by: Marcin Woźniak <y0rune@aol.com>

net-misc/meganz-sdk/Manifest

@@ -1 +1 @@
-DIST meganz-sdk-3.7.1.tar.gz 3293250 BLAKE2B c18578dd134060680070601aae4f4778f14228931cfb06e4a1b2e98622a58866354c56fc529ea8f34a6980581d464ff76c82806c456cd4b9193b083b3ad367a5 SHA512 f6ce9e286e69c1560d1f7a7b13b28e8e2ba77802e777a29bef132a09f32f5fc379e5c7f64845424081d682723c53760593442e0a71d01a497b83723c875b2d9a
+DIST meganz-sdk-3.7.3.tar.gz 3322179 BLAKE2B c8f5f9bea8b1e030f24ae79f0fddf8027d9f770b30762caa1f013d1ca19b40a8bf7451ad6b056743c55d71c48014298f005cbc0f3b24edd932da3ba3edba62e0 SHA512 d85f04cc1cd4c1320f0e01a6d2bd52522f502f91f06ba275c8dbf0f3fb751ac195054376cf97fe7eb93934c37f68614164232486f5d3c296dc830896ca60dea9

net-misc/meganz-sdk/meganz-sdk-3.7.1.ebuild

@@ -1 +0,0 @@
-meganz-sdk-9999.ebuild

net-misc/meganz-sdk/meganz-sdk-3.7.3.ebuild

@@ -0,0 +1,107 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic qmake-utils autotools db-use
+if [[ -z ${PV%%*9999} ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN%-*}/${PN#*-}.git"
+else
+	SRC_URI="https://github.com/meganz/sdk/archive/v${PV}d.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/sdk-${PV}d"
+	RESTRICT="primaryuri"
+	KEYWORDS="~amd64 ~x86"
+fi
+DESCRIPTION="MEGA C++ SDK"
+HOMEPAGE="https://github.com/meganz/sdk"
+
+LICENSE="BSD-2"
+SLOT="0/30701"
+IUSE="examples ffmpeg freeimage fuse hardened inotify libuv mediainfo qt raw +sqlite test"
+REQUIRED_USE="
+	examples? ( sqlite )
+	fuse? ( examples )
+"
+# tests require a working mega.nz account and login details provided via $MEGA_EMAIL and $MEGA_PWD
+RESTRICT+=" test"
+
+RDEPEND="
+	dev-libs/crypto++
+	sys-libs/zlib
+	dev-libs/libpcre:3[cxx]
+	dev-libs/openssl:0
+	net-dns/c-ares
+	net-misc/curl
+	sqlite? ( dev-db/sqlite:3 )
+	!sqlite? ( sys-libs/db:*[cxx] )
+	examples? (
+		sys-libs/readline:0
+		fuse? ( sys-fs/fuse:0 )
+	)
+	freeimage? ( media-libs/freeimage )
+	libuv? ( dev-libs/libuv )
+	dev-libs/libsodium
+	mediainfo? ( media-libs/libmediainfo )
+	ffmpeg? ( virtual/ffmpeg )
+	raw? ( media-libs/libraw )
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-cpp/gtest )
+"
+
+pkg_setup() {
+	use sqlite || append-cppflags "-I$(db_includedir)"
+}
+
+src_prepare() {
+	default
+	use qt && sed \
+		-e '/SOURCES += src\// s:+:-:' \
+		-e '/!exists.*config.h/ s:!::' \
+		-e 's:CONFIG(USE_MEGAAPI) {:&\nLIBS += -lmega:' \
+		-e '/^unix:!macx {/,/^}/d' \
+		-i bindings/qt/sdk.pri
+	use test && sed \
+		-e 's:\$(GTEST_DIR)/lib/lib\([^ ]\+\)\.la:-l\1:g' \
+		-e 's: tests/tool_purge_account::' \
+		-i tests/include.am
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-chat
+		$(use_enable inotify)
+		$(use_enable hardened gcc-hardening)
+		$(use_with libuv)
+		$(use_with !sqlite db)
+		$(use_with sqlite)
+		$(use_enable examples)
+		$(use_enable test tests)
+		$(use_with freeimage)
+		$(use_with fuse)
+		$(use_with mediainfo libmediainfo)
+		$(use_with ffmpeg)
+		$(use_with raw libraw)
+	)
+	use test && myeconfargs+=(
+		--with-gtest="${EPREFIX}/usr"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	export MEGA_EMAIL MEGA_PWD MEGA_EMAIL_AUX="${MEGA_EMAIL}" MEGA_PWD_AUX="${MEGA_PWD}"
+	default
+}
+
+src_install() {
+	default
+	doheader -r include/mega
+
+	use qt || return
+	insinto /usr/share/${PN}/bindings/qt
+	doins bindings/qt/*.{h,cpp,pri}
+}

net-misc/meganz-sdk/meganz-sdk-9999.ebuild

@@ -8,22 +8,15 @@ if [[ -z ${PV%%*9999} ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/${PN%-*}/${PN#*-}.git"
 else
-	inherit vcs-snapshot
+	SRC_URI="https://github.com/meganz/sdk/archive/v${PV}d.tar.gz -> ${P}.tar.gz"
-	MY_PV="b2948c7"
+	S="${WORKDIR}/sdk-${PV}d"
-	[[ -n ${PV%%*_p*} ]] && MY_PV="v${PV}"
-	SRC_URI="
-		mirror://githubcl/${PN%-*}/${PN#*-}/tar.gz/${MY_PV}
-		-> ${P}.tar.gz
-	"
 	RESTRICT="primaryuri"
 	KEYWORDS="~amd64 ~x86"
 fi
-
 DESCRIPTION="MEGA C++ SDK"
 HOMEPAGE="https://github.com/meganz/sdk"
 
 LICENSE="BSD-2"
-# awk '/define/ {print $3}' include/mega/version.h|awk 'BEGIN{RS="";FS="\n"}{printf $1*10000+$2*100+$3}'
 SLOT="0/30701"
 IUSE="examples ffmpeg freeimage fuse hardened inotify libuv mediainfo qt raw +sqlite test"
 REQUIRED_USE="