media-sound/fooyin: new package, add 0.5.3

Signed-off-by: SigHunter <sighunter@gmx.de>

media-sound/fooyin/Manifest

@@ -0,0 +1 @@
+DIST fooyin-0.5.3.tar.gz 4345101 BLAKE2B 351fc8337d424a2a8abeea33979645862208e150bd06b638a9e5c5f02c52299707935208c1f4b9f1c4876e702924f1701251e2158e1f22d50f65363ff137c137 SHA512 61356c0db34eee3a939a86fc867690f3c2389bb6a235b2e06975ce1bc83221bb8f8e9b684269510518147d5b4d203645db1bba96d574fcf01a16ec3b5222f47c

media-sound/fooyin/fooyin-0.5.3.ebuild

@@ -0,0 +1,68 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A customizable music player, Qt clone of foobar2000"
+HOMEPAGE="https://www.fooyin.org/"
+SRC_URI="
+	https://github.com/fooyin/fooyin/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="alsa pipewire sdl test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="|| ( alsa pipewire sdl )"
+
+RDEPEND="
+	dev-libs/icu:=
+	dev-qt/kdsingleapplication[qt6]
+	dev-qt/qtbase:6[concurrent,dbus,gui,network,sql,widgets]
+	media-libs/taglib
+	media-video/ffmpeg:=
+	alsa? ( media-libs/alsa-lib )
+	pipewire? ( media-video/pipewire:= )
+	sdl? ( media-libs/libsdl2 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? ( dev-cpp/gtest )
+"
+
+src_prepare() {
+	sed -i CMakeLists.txt \
+		-e "s|/doc/${PN}|/doc/${PF}|g" \
+		-e '/option(BUILD_TESTING/aenable_testing()' \
+		|| die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test)
+		-DBUILD_CCACHE=OFF
+		-DINSTALL_HEADERS=ON
+		$(cmake_use_find_package alsa ALSA)
+		$(cmake_use_find_package pipewire PipeWire)
+		$(cmake_use_find_package sdl SDL2)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local CMAKE_SKIP_TESTS=(
+		# TODO: figure out why these tests fail to find their test data
+		TagReaderTest.*
+		TagWriterTest.*
+	)
+
+	cmake_src_test
+}

media-sound/fooyin/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sighunter@gmx.de</email>
+		<name>SigHunter</name>
+	</maintainer>
+	<use>
+		<flag name="pipewire">Enable sound support via native PipeWire backend</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">fooyin/fooyin</remote-id>
+	</upstream>
+</pkgmetadata>
+