polybar: add polybar

x11-misc/polybar/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <use>
+    <flag name="i3wm">Add support for i3 window manager</flag>
+    <flag name="ipc">Add support for Inter-Process Messaging</flag>
+    <flag name="mpd">Add support for Music Player Daemon</flag>
+    <flag name="network">Enable network support</flag>
+  </use>
+  <upstream>
+    <remote-id type="github">polybar/polybar</remote-id>
+  </upstream>
+</pkgmetadata>

x11-misc/polybar/polybar-9999.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_6 python3_7 python3_8 )
+
+inherit cmake-utils python-single-r1 git-r3
+
+DESCRIPTION="A fast and easy-to-use status bar"
+HOMEPAGE="https://github.com/polybar/polybar"
+EGIT_REPO_URI="https://github.com/polybar/${PN}.git"
+EGIT_CLONE_TYPE="shallow"
+
+LICENSE="MIT"
+SLOT="0"
+
+IUSE="alsa curl i3wm ipc mpd network pulseaudio"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	x11-base/xcb-proto
+	x11-libs/cairo[xcb]
+	x11-libs/libxcb[xkb]
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-wm
+	x11-libs/xcb-util-xrm
+	alsa? ( media-libs/alsa-lib )
+	curl? ( net-misc/curl )
+	i3wm? ( dev-libs/jsoncpp )
+	mpd? ( media-libs/libmpdclient )
+	network? ( net-wireless/wireless-tools )
+	pulseaudio? ( media-sound/pulseaudio )
+"
+
+RDEPEND="
+	${DEPEND}
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_ALSA="$(usex alsa)"
+		-DENABLE_CURL="$(usex curl)"
+		-DENABLE_I3="$(usex i3wm)"
+		-DBUILD_IPC_MSG="$(usex ipc)"
+		-DENABLE_MPD="$(usex mpd)"
+		-DENABLE_NETWORK="$(usex network)"
+		-DENABLE_PULSEAUDIO="$(usex pulseaudio)"
+	)
+
+	cmake-utils_src_configure
+}