media-gfx/drawing: add 1.0.2

Signed-off-by: Alfred Wingate <parona@protonmail.com>

media-gfx/drawing/Manifest

@@ -1 +1,2 @@
 DIST drawing-1.0.1.tar.gz 14388196 BLAKE2B a3a1c392b8b33f27d172afd82f7654468799bc888e0e503f7c918b428bee839bf80e0fae461ac85808343dce392ac3856c1c63e352609a22bac32c01b3bdbb6a SHA512 68d1381e56233eded1562aa3632a4ae3e0afb0b2835530cfab8d30c56557d2e04915ef153b7965abe3ba00d603c7b0e354f37c088df382bb4345d55dc3fe7c2e
+DIST drawing-1.0.2.tar.gz 14407277 BLAKE2B 10b4c228ec87033dca5593bd69df683989cd49f2e420ce8d6357fb549ec46f1556829e87977dd3b118ea2b81cde56437f3346008bf8842d4e15db8de37d9a584 SHA512 61e3e2764832de6ed997bd6f72a63154fae332da76b12ede848b9c1e9d850ba46cf9ebdf16dd1b4d52827b5ec4e877aca03877d0557a2a2635279598992832d6

media-gfx/drawing/drawing-1.0.2.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="A drawing application for the GNOME desktop"
+HOMEPAGE="https://github.com/maoschanz/drawing"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/maoschanz/drawing.git"
+else
+	SRC_URI="https://github.com/maoschanz/drawing/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# tests are not useful
+RESTRICT="test"
+
+DEPEND="
+	${PYTHON_DEPS}
+	dev-libs/glib:2
+	x11-libs/gtk+:3
+	$(python_gen_cond_dep '
+		dev-python/pygobject[cairo,${PYTHON_USEDEP}]
+	')
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/itstool
+	sys-devel/gettext
+"
+
+src_configure() {
+	local emesonargs=(
+		-Denable-translations-and-appdata=true
+		-Duse-uuid-as-binary-name=false
+	)
+	meson_src_configure
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	gnome2_gconf_install
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_gconf_uninstall
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}