dev-libs/sdl-kitchensink: add 1.0.12

Signed-off-by: Alfred Wingate <parona@protonmail.com>

dev-libs/sdl-kitchensink/Manifest

@@ -1 +1,2 @@
+DIST sdl-kitchensink-1.0.12.tar.gz 76856 BLAKE2B dbb0222255f5b6712f59b1629bb9dae0bf1011b6f8f6914cb055df061aaeeb3896867cf8e556569ed6bf831089d1d4cc349f1cb43824e6e4485c4a11d2de84ea SHA512 7f254a62cf4d7e42790d39ddcf94a89a5195daa9cf591e62d7262c98042c64637b9e7c5878397d5683fdd0ad3503825897e0e074c78c30e2c8bfe34a3ee3c9e3
 DIST sdl-kitchensink-1.0.8.tar.gz 74969 BLAKE2B 21960457fb00032ff6a4cfb586379b6bc29682daf4dfda3fbecfa765ab6b05a6672c967c4aecdc338f5036d8ab38bd2d61491ea24774fa342af2a09621a5a040 SHA512 9ed8b1bf594c45723965ca717615d23d654c90d6b2720ccf98d0e569e51bc0d69292f2f918f910e1e2971a1cfe4523d844f8d0b26da52e28a65fba25a4a7576b

dev-libs/sdl-kitchensink/sdl-kitchensink-1.0.12.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="A Simple SDL2 / FFmpeg library for audio/video playback written in C99"
+HOMEPAGE="https://github.com/katajakasa/SDL_kitchensink"
+SRC_URI="https://github.com/katajakasa/SDL_kitchensink/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/SDL_kitchensink-${PV}"
+
+KEYWORDS="~amd64"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc examples"
+
+# no tests
+RESTRICT="test"
+
+RDEPEND="
+	>=media-libs/libsdl2-2.0.5
+	>=media-video/ffmpeg-3.2:=
+	media-libs/libass:=
+"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Install examples
+	sed -i \
+		-e 's/set_property(TARGET ${TARGET} PROPERTY \(.*\))/\
+		set_target_properties(${TARGET} PROPERTIES OUTPUT_NAME "SDL_kitchensink-${TARGET}" \1)/' \
+		-e '/add_executable(${TARGET}/ a\\tinstall(TARGETS ${TARGET})' \
+		CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_EXAMPLES="$(usex examples)"
+		-DBUILD_SHARED=ON
+		-DBUILD_STATIC=OFF
+		-DUSE_ASAN=OFF
+		-DUSE_DYNAMIC_LIBASS=OFF
+		-DUSE_TIDY=OFF
+	)
+	cmake_src_configure
+}
+
+src_compile () {
+	cmake_src_compile
+
+	use doc && cmake_build docs
+}
+
+src_install() {
+	cmake_src_install
+
+	if use doc; then
+		dodoc -r "${S}"/docs/html
+	fi
+}
+
+pkg_postinst() {
+	if use examples; then
+		for i in audio complex custom rwops simple; do
+			einfo "Installed ${i} example as SDL_kitchensink-${i}"
+		done
+	fi
+}