From ca2565a37cb51fc2e2aa2fbd3974c868974f7a4f Mon Sep 17 00:00:00 2001
From: Alfred Wingate <parona@protonmail.com>
Date: Mon, 4 Dec 2023 13:41:22 +0200
Subject: [PATCH] media-gfx/akira: add 0.0.15_alpha_pre20231116

Signed-off-by: Alfred Wingate <parona@protonmail.com>
---
 media-gfx/akira/Manifest                      |  1 +
 .../akira-0.0.15_alpha_pre20231116.ebuild     | 89 +++++++++++++++++++
 media-gfx/akira/akira-9999.ebuild             | 64 +++++++++----
 3 files changed, 136 insertions(+), 18 deletions(-)
 create mode 100644 media-gfx/akira/akira-0.0.15_alpha_pre20231116.ebuild

diff --git a/media-gfx/akira/Manifest b/media-gfx/akira/Manifest
index 2fe668a..2478e06 100644
--- a/media-gfx/akira/Manifest
+++ b/media-gfx/akira/Manifest
@@ -1 +1,2 @@
 DIST akira-0.0.13.tar.gz 899335 BLAKE2B a995bf6083bec24f32e84adfc5551f620877d0ce98b18ff33c7eef57c8401bf8964c9104278691f997024670c8df97d451effba469991eb2d44ee37c166a082e SHA512 e8fbdeb37e1679ef3ee640da4bb37a19c40549b6006291b3dafe7cf56c9436da1ef303232040de8d58dafc5eb110317c77feb21b9e4582520e7baa52f871cd5e
+DIST akira-3b6c58ab4376f0c40cf647164354a65ba2b15a3f.tar.gz 1000439 BLAKE2B e5940adcf00543f19c349bbcbd1841cb67512e5ad0617c55b63f764e0879356650048a10b32561a0849d1091d07a2a8a2f3d9a43082c037c3494cb85f1f40494 SHA512 cdf2648bb7f4910967039682b21ac488b5fb873aba877af02660d0e102672ebeaca4079d30d44aa13ea3e6608be11a5962e15c47fba61224f221c58489b67d37
diff --git a/media-gfx/akira/akira-0.0.15_alpha_pre20231116.ebuild b/media-gfx/akira/akira-0.0.15_alpha_pre20231116.ebuild
new file mode 100644
index 0000000..19d7d97
--- /dev/null
+++ b/media-gfx/akira/akira-0.0.15_alpha_pre20231116.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson vala virtualx xdg
+
+DESCRIPTION="Native Linux App for UI and UX Design built in Vala and Gtk "
+HOMEPAGE="https://github.com/akiraux/akira"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/akiraux/${PN}.git"
+else
+	COMMIT="3b6c58ab4376f0c40cf647164354a65ba2b15a3f"
+	SRC_URI="https://github.com/akiraux/Akira/archive/${COMMIT}.tar.gz -> ${PN}-${COMMIT}.tar.gz"
+	S="${WORKDIR}/${PN^}-${COMMIT}"
+
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-arch/libarchive
+	>=dev-libs/granite-6.0.0
+	dev-libs/json-glib
+	dev-libs/libgee:0.8
+	dev-libs/libxml2
+	>=x11-libs/cairo-1.14
+	x11-libs/gtk+:3
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+"
+
+pkg_setup() {
+	vala_setup
+}
+
+src_prepare() {
+	eapply_user
+
+	# Remove automagic test dependencies
+	sed -i \
+		-e 's/\(appstream_util =\) .*/\1 disabler()/' \
+		-e 's/\(desktop_file_validate =\) .*/\1 disabler()/' \
+		-e 's/\(vala_lint =\) .*/\1 disabler()/' \
+		meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test install-tests)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	dosym com.github.akiraux.akira /usr/bin/akira
+}
+
+src_test() {
+	local -x PATH="${BUILD_DIR}/tests:${PATH}"
+	local -x top_builddir="${S}"
+	virtx meson_src_test
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/media-gfx/akira/akira-9999.ebuild b/media-gfx/akira/akira-9999.ebuild
index cac4697..19d7d97 100644
--- a/media-gfx/akira/akira-9999.ebuild
+++ b/media-gfx/akira/akira-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-inherit gnome2-utils vala xdg meson
+inherit gnome2-utils meson vala virtualx xdg
 
 DESCRIPTION="Native Linux App for UI and UX Design built in Vala and Gtk "
 HOMEPAGE="https://github.com/akiraux/akira"
@@ -12,37 +12,65 @@ if [[ "${PV}" == *9999* ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/akiraux/${PN}.git"
 else
-	SRC_URI="https://github.com/akiraux/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	COMMIT="3b6c58ab4376f0c40cf647164354a65ba2b15a3f"
+	SRC_URI="https://github.com/akiraux/Akira/archive/${COMMIT}.tar.gz -> ${PN}-${COMMIT}.tar.gz"
+	S="${WORKDIR}/${PN^}-${COMMIT}"
+
 	KEYWORDS="~amd64"
-	S="${WORKDIR}/${P^}"
 fi
 
-RESTRICT="mirror test"
 LICENSE="GPL-3"
 SLOT="0"
 
-DEPEND="
-	>=dev-libs/granite-5.3.0
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
 	app-arch/libarchive
-	dev-libs/gobject-introspection
+	>=dev-libs/granite-6.0.0
 	dev-libs/json-glib
-	dev-libs/libgee
+	dev-libs/libgee:0.8
 	dev-libs/libxml2
-	sys-devel/gettext
-	x11-libs/goocanvas:2.0
-	x11-libs/gtksourceview:4
+	>=x11-libs/cairo-1.14
+	x11-libs/gtk+:3
 "
-RDEPEND="${DEPEND}"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+"
+
+pkg_setup() {
+	vala_setup
+}
 
 src_prepare() {
-	xdg_environment_reset
-	vala_src_prepare
-	default
+	eapply_user
+
+	# Remove automagic test dependencies
+	sed -i \
+		-e 's/\(appstream_util =\) .*/\1 disabler()/' \
+		-e 's/\(desktop_file_validate =\) .*/\1 disabler()/' \
+		-e 's/\(vala_lint =\) .*/\1 disabler()/' \
+		meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test install-tests)
+	)
+
+	meson_src_configure
 }
 
 src_install() {
 	meson_src_install
-	dosym "${EPREFIX}/usr/bin/com.github.akiraux.${PN}" "${EPREFIX}/usr/bin/${PN}"
+	dosym com.github.akiraux.akira /usr/bin/akira
+}
+
+src_test() {
+	local -x PATH="${BUILD_DIR}/tests:${PATH}"
+	local -x top_builddir="${S}"
+	virtx meson_src_test
 }
 
 pkg_preinst() {