diff --git a/dev-python/python-olm/Manifest b/dev-python/python-olm/Manifest
index 75abd2e..f5e4eb8 100644
--- a/dev-python/python-olm/Manifest
+++ b/dev-python/python-olm/Manifest
@@ -1 +1,2 @@
 DIST olm-3.2.15.tar.bz2 2744760 BLAKE2B 44486a63217998010a0bb7e01ff3315c88e139d686b97158e67af29b2f052912412541fb944a17c5d8931df9c641a73e521ef8d0ff352b80fe30bd6fb73b2e7b SHA512 81832766e477fc17908e8d1c49b5403d87b5977fd9102605d95ef2a3907619b7301e32fe0e18ec0f575b1f004ce248633307ff43b0f48bc9bb2313cdfefd6ea7
+DIST olm-3.2.16.tar.bz2 2744360 BLAKE2B 236cd08cb4f014ef4f90377fe30907490dbf6482629ab47a779114c711de1855c44874a45ee92f4f55d7c100abbbde2c427996ce534dd95ce401a7549db351b7 SHA512 504ddc91297e7aef99e9b25f73b33bac29716ca33eb333bf1217b719d8862438e2cdaadd88cef3dc84e9f618bcc9eeeaf7e513f2d6909cc4a3d98a5dd79b0581
diff --git a/dev-python/python-olm/python-olm-3.2.16.ebuild b/dev-python/python-olm/python-olm-3.2.16.ebuild
new file mode 100644
index 0000000..a98910a
--- /dev/null
+++ b/dev-python/python-olm/python-olm-3.2.16.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="python CFFI bindings for the olm cryptographic ratchet library"
+HOMEPAGE="
+	https://gitlab.matrix.org/matrix-org/olm
+	https://pypi.org/project/python-olm/
+"
+SRC_URI="https://gitlab.matrix.org/matrix-org/olm/-/archive/${PV}/olm-${PV}.tar.bz2"
+S="${WORKDIR}/olm-${PV}/python/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# special case where only python bindings were modified
+DEPEND="
+	|| (
+		~dev-libs/olm-${PV}
+		~dev-libs/olm-3.2.15[-python(-)]
+	)
+	dev-python/cffi[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	test? (
+		dev-python/aspectlib[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# deselect tests using benchmark fixtures
+	"tests/group_session_test.py::TestClass::test_encrypt"
+	"tests/group_session_test.py::TestClass::test_decrypt"
+)
+
+src_prepare() {
+	pushd "${WORKDIR}/olm-${PV}" > /dev/null || die
+	if [[ ${#PATCHES} > 0 ]]; then
+		eapply "${PATCHES[@]}"
+	fi
+	eapply_user
+	popd > /dev/null || die
+}