diff --git a/net-misc/meganz-sdk/Manifest b/net-misc/meganz-sdk/Manifest
index 57023e3..3a9ab42 100644
--- a/net-misc/meganz-sdk/Manifest
+++ b/net-misc/meganz-sdk/Manifest
@@ -1,2 +1,4 @@
+DIST meganz-sdk-3.7.3.tar.gz 3322179 BLAKE2B c8f5f9bea8b1e030f24ae79f0fddf8027d9f770b30762caa1f013d1ca19b40a8bf7451ad6b056743c55d71c48014298f005cbc0f3b24edd932da3ba3edba62e0 SHA512 d85f04cc1cd4c1320f0e01a6d2bd52522f502f91f06ba275c8dbf0f3fb751ac195054376cf97fe7eb93934c37f68614164232486f5d3c296dc830896ca60dea9
+DIST meganz-sdk-7.10.0.tar.gz 4203361 BLAKE2B b8624fa65d40086605d3debae0cea9c1d4167b2b4c54757ef5cf87f3a35cfff8d285a926b3ee12ddb03272e92a144062a1790a2189df38606d7c0741b802f4cf SHA512 6d5c648927225b01b2ef10961864093b51c3dabb2389e63a13fd2a59558ce46ac782f5bd4e16cc312c9975a3cbd8f86948f565ebd05188d6bb76693045b3ed09
 DIST meganz-sdk-7.12.0.tar.gz 4229704 BLAKE2B 895a3803f9c03858ae67097b69c7fbeb94a57a4873fdb9643728a92a804614c8ec22a67f9744bb5ffc4e6b551a18e3b809549a533fa731b33c1f28e77a8d22dc SHA512 4e4a0d6822a979ef9ccd587031de61a36a82be61ef87facd5de94ae056530a9eb793b0d2a2a5db8530a7e8664b6556705bad82345c2c01c6fb3e04fe8c511af7
 DIST meganz-sdk-7.13.0.tar.gz 4252498 BLAKE2B 32bc0ac25607b63ff2ddf0016a541a521539a3bef76158007e5f404aacf45ac17a360f232f64335231a2cb2db9617452c4223f16ee03f717189275aa08d1929a SHA512 0bc1805eb43a74f02bc8e0f8a71c4e7c3d7152f45b76c062c82ba0e023f50404b73330ed2970f1c88935a3ec190af29fc944c90cbeb360e63fa0fd1dcbb915f9
diff --git a/net-misc/meganz-sdk/meganz-sdk-3.7.3.ebuild b/net-misc/meganz-sdk/meganz-sdk-3.7.3.ebuild
new file mode 100644
index 0000000..e951766
--- /dev/null
+++ b/net-misc/meganz-sdk/meganz-sdk-3.7.3.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic qmake-utils autotools db-use
+if [[ -z ${PV%%*9999} ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN%-*}/${PN#*-}.git"
+else
+	SRC_URI="https://github.com/meganz/sdk/archive/v${PV}d.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/sdk-${PV}d"
+	RESTRICT="primaryuri"
+	KEYWORDS="~amd64 ~x86"
+fi
+DESCRIPTION="MEGA C++ SDK"
+HOMEPAGE="https://github.com/meganz/sdk"
+
+LICENSE="BSD-2"
+SLOT="0/30701"
+IUSE="examples ffmpeg freeimage fuse hardened inotify libuv mediainfo qt raw +sqlite test"
+REQUIRED_USE="
+	examples? ( sqlite )
+	fuse? ( examples )
+"
+# tests require a working mega.nz account and login details provided via $MEGA_EMAIL and $MEGA_PWD
+RESTRICT+=" test"
+
+RDEPEND="
+	dev-libs/crypto++
+	sys-libs/zlib
+	dev-libs/libpcre:3[cxx]
+	dev-libs/openssl:0
+	net-dns/c-ares
+	net-misc/curl
+	sqlite? ( dev-db/sqlite:3 )
+	!sqlite? ( sys-libs/db:*[cxx] )
+	examples? (
+		sys-libs/readline:0
+		fuse? ( sys-fs/fuse:0 )
+	)
+	freeimage? ( media-libs/freeimage )
+	libuv? ( dev-libs/libuv )
+	dev-libs/libsodium
+	mediainfo? ( media-libs/libmediainfo )
+	ffmpeg? ( media-video/ffmpeg )
+	raw? ( media-libs/libraw )
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-cpp/gtest )
+"
+
+pkg_setup() {
+	use sqlite || append-cppflags "-I$(db_includedir)"
+}
+
+src_prepare() {
+	default
+	use qt && sed \
+		-e '/SOURCES += src\// s:+:-:' \
+		-e '/!exists.*config.h/ s:!::' \
+		-e 's:CONFIG(USE_MEGAAPI) {:&\nLIBS += -lmega:' \
+		-e '/^unix:!macx {/,/^}/d' \
+		-i bindings/qt/sdk.pri
+	use test && sed \
+		-e 's:\$(GTEST_DIR)/lib/lib\([^ ]\+\)\.la:-l\1:g' \
+		-e 's: tests/tool_purge_account::' \
+		-i tests/include.am
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-chat
+		$(use_enable inotify)
+		$(use_enable hardened gcc-hardening)
+		$(use_with libuv)
+		$(use_with !sqlite db)
+		$(use_with sqlite)
+		$(use_enable examples)
+		$(use_enable test tests)
+		$(use_with freeimage)
+		$(use_with fuse)
+		$(use_with mediainfo libmediainfo)
+		$(use_with ffmpeg)
+		$(use_with raw libraw)
+	)
+	use test && myeconfargs+=(
+		--with-gtest="${EPREFIX}/usr"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	export MEGA_EMAIL MEGA_PWD MEGA_EMAIL_AUX="${MEGA_EMAIL}" MEGA_PWD_AUX="${MEGA_PWD}"
+	default
+}
+
+src_install() {
+	default
+	doheader -r include/mega
+
+	use qt || return
+	insinto /usr/share/${PN}/bindings/qt
+	doins bindings/qt/*.{h,cpp,pri}
+}
diff --git a/net-misc/meganz-sdk/meganz-sdk-7.10.0.ebuild b/net-misc/meganz-sdk/meganz-sdk-7.10.0.ebuild
new file mode 100644
index 0000000..fc4e932
--- /dev/null
+++ b/net-misc/meganz-sdk/meganz-sdk-7.10.0.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="MEGA C++ SDK"
+HOMEPAGE="https://github.com/meganz/sdk"
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/meganz/sdk.git"
+else
+	SRC_URI="https://github.com/meganz/sdk/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/sdk-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="BSD-2"
+SLOT="0/${PV}"
+IUSE="examples ffmpeg freeimage fuse libuv mediainfo qt test"
+
+RESTRICT="!test? ( test )"
+
+# <ffmpeg-6: https://github.com/meganz/sdk/issues/2635
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/crypto++:=
+	dev-libs/icu:=
+	dev-libs/libsodium:=
+	dev-libs/openssl:=
+	net-dns/c-ares:=
+	net-misc/curl
+	ffmpeg? ( <media-video/ffmpeg-6 )
+	freeimage? ( media-libs/freeimage )
+	fuse? ( sys-fs/fuse )
+	libuv? ( dev-libs/libuv:= )
+	mediainfo? (
+		media-libs/libmediainfo
+		media-libs/libzen
+	)
+	qt? ( dev-qt/qtcore:5 )
+"
+DEPEND="
+	${RDEPEND}
+	sys-libs/readline
+"
+
+src_prepare() {
+	# 1. Mismatched pkgconfig file names
+	# 2. Symbols still needed publically when linking library
+	sed -i \
+		-e '/pkg_check_modules/ s/libcrypto++/libcryptopp/' \
+		-e '/target_link_libraries(SDKlib/ { /\(curl\|sodium\)/ s/PRIVATE/PUBLIC/ }' \
+		contrib/cmake/modules/sdklib_libraries.cmake || die
+
+	sed -i \
+		-e 's|DESTINATION cmake|DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake|' \
+		-e 's|DESTINATION pkgconfig|DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig|' \
+		contrib/cmake/modules/sdklib_target.cmake || die
+
+	# examples use readline symbols
+	sed -i \
+		-e 's/target_link_libraries(megacli PRIVATE MEGA::SDKlib)/target_link_libraries(megacli PRIVATE MEGA::SDKlib PkgConfig::readline)/' \
+		examples/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# building with DEBUG disabled isn't tested apparently
+	# https://github.com/meganz/sdk/issues/2658
+	append-cppflags -DDEBUG=1
+
+	local mycmakeargs=(
+		# CMakeLists.txt
+		# contrib/cmake/modules/sdklib_options.cmake
+
+		-DENABLE_ISOLATED_GFX=OFF # required freeimage + doesn't properly link libz
+		-DENABLE_QT_BINDINGS=$(usex qt) # doesn't get installed
+		-DENABLE_SDKLIB_EXAMPLES=$(usex examples)
+		-DENABLE_SDKLIB_TESTS=$(usex test)
+		-DENABLE_SDKLIB_WERROR=OFF
+		-DUSE_FFMPEG=$(usex ffmpeg)
+		-DUSE_C_ARES=ON
+		-DUSE_FREEIMAGE=$(usex freeimage)
+		-DUSE_LIBUV=$(usex libuv)
+		-DUSE_MEDIAINFO=$(usex mediainfo)
+		-DUSE_OPENSSL=ON
+		-DUSE_PDFIUM=OFF # unpackaged
+		-DUSE_READLINE=ON
+		-DWITH_FUSE=$(usex fuse)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	set -- "${BUILD_DIR}"/tests/unit/test_unit
+	einfo ${@}
+	${@} || die
+
+	# integration test require a mega account and will be destructive, which is why they aren't run.
+	# IMPORTANT: the main account must be empty (Cloud & Rubbish) before starting the test and it will be purged at exit.
+	# Both main and auxiliar accounts shouldn't be contacts yet and shouldn't have any pending contact requests.
+	# Set your login credentials as environment variables:
+	# * $MEGA_EMAIL and $MEGA_PWD (and $MEGA_EMAIL_AUX / $MEGA_PWD_AUX for shares * contacts)
+}
+
+src_install() {
+	cmake_src_install
+
+	doheader -r include/mega
+
+	if use qt; then
+		dolib.so "${BUILD_DIR}"/bindings/qt/libSDKQtBindings.so
+		insinto /usr/share/${PN}/bindings/qt
+		doins bindings/qt/*.{h,cpp}
+	fi
+}