From 73ed73b6204fb288ddbf0eabf9bcc09f95c2636e Mon Sep 17 00:00:00 2001
From: medanisjbara <anis2834133766619@gmail.com>
Date: Thu, 8 Dec 2022 11:22:50 +0100
Subject: [PATCH] media-gfx/swayimg: add swayimg-1.9

---
 media-gfx/swayimg/Manifest           |  1 +
 media-gfx/swayimg/metadata.xml       | 15 +++++++
 media-gfx/swayimg/swayimg-1.9.ebuild | 64 ++++++++++++++++++++++++++++
 3 files changed, 80 insertions(+)
 create mode 100644 media-gfx/swayimg/Manifest
 create mode 100644 media-gfx/swayimg/metadata.xml
 create mode 100644 media-gfx/swayimg/swayimg-1.9.ebuild

diff --git a/media-gfx/swayimg/Manifest b/media-gfx/swayimg/Manifest
new file mode 100644
index 0000000..cd332f3
--- /dev/null
+++ b/media-gfx/swayimg/Manifest
@@ -0,0 +1 @@
+DIST swayimg-1.9.tar.gz 387087 BLAKE2B 16de84a27b8dd3bb6003cb5280d5719482b28c5706da96290643d4019394a0c96043e3390829b982d64d35aa288df84d1f3dc4bc1f962346e6d2f07f554caea5 SHA512 5eccb69f53accb0229be6260563e18e3534bcc9d711cdde8325c8100fa765f698b15c51356136a802cfc7d384a433beb8cff98d625b035bd4a5d9de076ff01bc
diff --git a/media-gfx/swayimg/metadata.xml b/media-gfx/swayimg/metadata.xml
new file mode 100644
index 0000000..c4afad4
--- /dev/null
+++ b/media-gfx/swayimg/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="person">
+  <email>med.anis.jbara.2000@gmail.com</email>
+  <name>Med Anis Jbara</name>
+</maintainer>
+<upstream>
+  <remote-id type="github">artemsen/swayimg</remote-id>
+</upstream>
+<use>
+  <flag name="heif">Support for HEIF and AVIF image formats</flag>
+  <flag name="jpegxl">Support for JPEG XL image format</flag>
+</use>
+</pkgmetadata>
diff --git a/media-gfx/swayimg/swayimg-1.9.ebuild b/media-gfx/swayimg/swayimg-1.9.ebuild
new file mode 100644
index 0000000..92cdf4a
--- /dev/null
+++ b/media-gfx/swayimg/swayimg-1.9.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1 meson xdg
+
+DESCRIPTION="A lightweight image viewer for Sway/Wayland display servers."
+HOMEPAGE="https://github.com/artemsen/swayimg"
+SRC_URI="https://github.com/artemsen/swayimg/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+COMMUN_DEPEND="
+	dev-libs/json-c
+	dev-libs/wayland
+	media-libs/fontconfig
+	media-libs/freetype
+	x11-libs/libxkbcommon
+	exif? ( media-libs/libexif )
+	gif? ( media-libs/giflib )
+	heif? ( media-libs/libheif )
+	jpeg? ( media-libs/libjpeg-turbo )
+	jpegxl? ( media-libs/libjxl )
+	png? ( media-libs/libpng )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff )
+	webp? ( media-libs/libwebp )"
+
+RDEPEND="${COMMUN_DEPEND}"
+
+DEPEND="
+	${COMMUN_DEPEND}
+	dev-libs/wayland-protocols"
+
+BDEPEND="
+	dev-util/wayland-scanner"
+
+IUSE="exif gif heif jpeg jpegxl png svg tiff webp"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature exif)
+		$(meson_feature gif)
+		$(meson_feature heif)
+		$(meson_feature jpeg)
+		$(meson_feature jpegxl jxl)
+		$(meson_feature png)
+		$(meson_feature svg)
+		$(meson_feature tiff)
+		$(meson_feature webp)
+		-Ddesktop=true
+		-Dman=true
+		-Dzsh=true
+	)
+	meson_src_configure
+}
+
+src_install(){
+	meson_src_install
+	newbashcomp extra/bash.completion ${PN}
+}