From 49a83f2be014a23b1f27aeb3eff29a71a03056d4 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Maciej=20Bar=C4=87?= <xgqt@protonmail.com>
Date: Mon, 18 Jan 2021 14:01:18 +0100
Subject: [PATCH] dev-libs/granite: bump to 5.5.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Maciej Barć <xgqt@protonmail.com>
---
 dev-libs/granite/Manifest             |  1 +
 dev-libs/granite/granite-5.5.0.ebuild | 79 +++++++++++++++++++++++++++
 2 files changed, 80 insertions(+)
 create mode 100644 dev-libs/granite/granite-5.5.0.ebuild

diff --git a/dev-libs/granite/Manifest b/dev-libs/granite/Manifest
index f554324..f481e93 100644
--- a/dev-libs/granite/Manifest
+++ b/dev-libs/granite/Manifest
@@ -1 +1,2 @@
 DIST granite-5.3.0.tar.gz 404331 BLAKE2B 44943f458a32f91dacfcbe8ecb26334fc5b410ee2b518b6c6d80f3c88bb642663891add54f767de20cba21a0829ebcce231c32b475c1875f319cdb4b0e3107ca SHA512 543f6344ec792a02f76f39eb803b6ff2386f0121dd61afcf6c3ae2f43b97fc01aacdb4022c9ce58c06a5d3e79d603cb397d4f95172e56fe9766902bf77d09342
+DIST granite-5.5.0.tar.gz 421478 BLAKE2B 9b6e956fcacf5dba722dd999ed3de527a99bd305a2059bdc39fe00d767f0f855e8f3a4d0854fd441203bb5dfbb250669356f85b64e067ddc08e3d6dfc3fb389d SHA512 981ff9aa42146153d8450989513dd6b63cfb6cf2e52cf3e1d2d6380373b30754d9b357418810cfd14a53689a050f08337ca766b5b8496a4063106f78b377f139
diff --git a/dev-libs/granite/granite-5.5.0.ebuild b/dev-libs/granite/granite-5.5.0.ebuild
new file mode 100644
index 0000000..7a1cf25
--- /dev/null
+++ b/dev-libs/granite/granite-5.5.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+VALA_MIN_API_VERSION=0.40
+BUILD_DIR="${WORKDIR}/${P}-build"
+
+inherit meson vala xdg
+
+DESCRIPTION="Elementary OS library that extends GTK+"
+HOMEPAGE="https://github.com/elementary/granite"
+SRC_URI="https://github.com/elementary/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc +introspection test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	$(vala_depend)
+	virtual/pkgconfig
+	doc? (
+		dev-lang/vala[valadoc]
+		dev-util/gtk-doc
+	)
+"
+DEPEND="
+	>=dev-libs/glib-2.50:2
+	dev-libs/libgee:0.8[introspection=]
+	>=x11-libs/gtk+-3.22:3[introspection=]
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	vala_src_prepare
+	if use doc; then
+		sed -i \
+			"s/find_program('valadoc')/find_program('valadoc-$(vala_best_api_version)')/g" \
+			doc/meson.build || die "Failed to replace valadoc"
+		local doc_sed_list=(
+			"lib/Widgets/AboutDialog.vala"
+			"lib/Widgets/AlertView.vala"
+			"lib/Widgets/AsyncImage.vala"
+			"lib/Widgets/Avatar.vala"
+			"lib/Widgets/CellRendererBadge.vala"
+			"lib/Widgets/DynamicNotebook.vala"
+			"lib/Widgets/MessageDialog.vala"
+			"lib/Widgets/ModeButton.vala"
+			"lib/Widgets/OverlayBar.vala"
+			"lib/Widgets/SeekBar.vala"
+			"lib/Widgets/StorageBar.vala"
+			"lib/Widgets/Toast.vala"
+			"lib/Widgets/Welcome.vala"
+		)
+		for src_file in "${doc_sed_list[@]}"; do
+			sed -ie "s@{{../doc@{{${BUILD_DIR}/doc@g" \
+				"./${src_file}" || die "Failed to fix docs for ./${src_file}"
+		done
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc documentation)
+	)
+	meson_src_configure
+
+	if use doc; then
+		cp -r ./doc/images "${BUILD_DIR}/doc/" || die "Failed to copy doc images"
+	fi
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}/doc/granite/html/." )
+	meson_src_install
+}